Datadog

Conecta Datadog para que los agentes puedan consultar tus logs, métricas, monitores y dashboards durante las investigaciones.

Configuración

1. Selecciona tu sitio de Datadog (US1, US3, US5, EU1, AP1, etc.). Comprueba tu URL de Datadog: app.datadoghq.com es US1, app.datadoghq.eu es EU1.
2. Introduce tu API key desde Organization Settings → API Keys.
3. Introduce tu Application key desde Organization Settings → Application Keys.
4. Polylane valida ambas claves y conecta.

Una clave de aplicación sin scopes tiene el mismo acceso que tu usuario y funciona tal cual. Si limitas la clave con scopes, incluye user_app_keys (necesario para conectar) más logs_read_data, timeseries_query, metrics_read, monitors_read, monitors_write, monitors_downtime, dashboards_read, slos_read, hosts_read, events_read, incident_read, apm_read, aws_configuration_read y create_webhooks. Tus claves se cifran antes de almacenarse, y el agente nunca las ve.

Conectar crea un webhook llamado polylane en Datadog y suscribe a él todos los monitores, así que las alertas llegan a Polylane y se triagean en cuanto se disparan.

Qué pueden hacer los agentes

• Buscar y filtrar logs con la sintaxis de consulta de Datadog
• Leer valores de métricas y tendencias a lo largo del tiempo
• Comprobar qué monitores están alertando y su estado
• Referenciar datos de dashboards en las investigaciones

Desconexión

Desconecta Datadog en Polylane y luego revoca la clave de aplicación y la clave de API en Datadog.

Polylane suscribe un monitor añadiendo la mención @webhook-polylane a su mensaje y agregando la etiqueta polylane:managed. Una sincronización recurrente aplica ambas a todos los monitores, así que un monitor gestionado con Terraform muestra drift hasta que su configuración de Terraform también las lleva. Añade ambas a cada monitor:

resource "datadog_monitor" "high_error_rate" {
  name  = "High error rate on checkout"
  type  = "metric alert"
  query = "sum(last_5m):sum:trace.http.request.errors{service:checkout}.as_count() > 50"

  message = <<-EOT
    {{#is_alert}}Error rate on checkout is above threshold.{{/is_alert}}
    @webhook-polylane
  EOT

  tags = concat(var.tags, ["polylane:managed"])
}

La configuración más sencilla deja el propio webhook gestionado por Polylane y pone en Terraform solo la mención y la etiqueta. Si también gestionas los webhooks en Terraform, importa el existente en lugar de crearlo, ya que los nombres de webhook de Datadog son únicos. Añade primero el bloque de recurso y luego importa:

resource "datadog_webhook" "polylane" {
  name      = "polylane"
  url       = "https://sinks.polylane.com/v1/datadog"
  encode_as = "json"

  custom_headers = jsonencode({
    "x-polylane-telemetry-token" = var.polylane_telemetry_token
  })

  payload = jsonencode({
    alert_id         = "$ALERT_ID"
    alert_metric     = "$ALERT_METRIC"
    alert_query      = "$ALERT_QUERY"
    alert_scope      = "$ALERT_SCOPE"
    alert_status     = "$ALERT_STATUS"
    alert_title      = "$ALERT_TITLE"
    alert_transition = "$ALERT_TRANSITION"
    alert_type       = "$ALERT_TYPE"
    date             = "$DATE_POSIX"
    event_msg        = "$EVENT_MSG"
    event_title      = "$EVENT_TITLE"
    event_type       = "$EVENT_TYPE"
    hostname         = "$HOSTNAME"
    id               = "$ID"
    link             = "$LINK"
    logs_sample      = "$LOGS_SAMPLE"
    org_id           = "$ORG_ID"
    org_name         = "$ORG_NAME"
    priority         = "$PRIORITY"
    snapshot         = "$SNAPSHOT"
    tags             = "$TAGS"
    user             = "$USER"
    username         = "$USERNAME"
  })
}

terraform import datadog_webhook.polylane polylane

El token de telemetría autentica las entregas de alertas a tu espacio de trabajo. Encuéntralo en Polylane en Settings → Telemetry tokens (el token llamado datadog-integration), o crea un token nuevo en la misma página. Reconectar la integración vuelve a crear el webhook con un token nuevo, así que un webhook importado necesita que su variable de token se actualice después.